who_need_help/lib/who_need_help/accounts/user.ex

defmodule WhoNeedHelp.Accounts.User do
  use Ecto.Schema
  import Ecto.Changeset

  @primary_key {:id, :binary_id, autogenerate: true}
  @foreign_key_type :binary_id
  schema "users" do
    field :email, :string
    field :password, :string, virtual: true, redact: true
    field :hashed_password, :string, redact: true
    field :confirmed_at, :utc_datetime
    field :authenticated_at, :utc_datetime, virtual: true
    field :display_name, :string
    field :bio, :string
    field :locale, :string, default: "en"

    field :location_visibility, Ecto.Enum,
      values: [:hidden, :approximate_public, :exact_for_active_match, :exact_public],
      default: :approximate_public

    field :direct_message_policy, Ecto.Enum,
      values: [:everyone, :verified_accounts, :completed_help_users, :nobody],
      default: :verified_accounts

    field :role, Ecto.Enum, values: [:user, :moderator, :admin], default: :user

    field :moderation_status, Ecto.Enum,
      values: [:active, :restricted, :suspended],
      default: :active

    field :moderation_note, :string
    field :tip_url, :string
    field :accepted_terms_at, :utc_datetime
    field :terms_accepted, :boolean, virtual: true, default: false
    has_many :social_identities, WhoNeedHelp.Accounts.SocialIdentity

    timestamps(type: :utc_datetime)
  end

  @doc """
  A user changeset for registering or changing the email.

  It requires the email to change otherwise an error is added.

  ## Options

    * `:validate_unique` - Set to false if you don't want to validate the
      uniqueness of the email, useful when displaying live validations.
      Defaults to `true`.
  """
  def email_changeset(user, attrs, opts \\ []) do
    user
    |> cast(attrs, [:email])
    |> validate_email(opts)
  end

  def registration_changeset(user, attrs, opts \\ []) do
    user
    |> cast(attrs, [:email, :display_name, :terms_accepted])
    |> validate_required([:display_name])
    |> validate_acceptance(:terms_accepted,
      message: "you must confirm that you are 18+ and accept the rules"
    )
    |> validate_length(:display_name, min: 2, max: 80)
    |> validate_email(opts)
    |> maybe_accept_terms()
  end

  defp maybe_accept_terms(changeset) do
    if get_change(changeset, :terms_accepted) == true do
      put_change(changeset, :accepted_terms_at, DateTime.utc_now(:second))
    else
      changeset
    end
  end

  def profile_changeset(user, attrs) do
    user
    |> cast(attrs, [
      :display_name,
      :bio,
      :locale,
      :location_visibility,
      :direct_message_policy,
      :tip_url
    ])
    |> validate_required([:display_name, :locale, :location_visibility, :direct_message_policy])
    |> validate_length(:display_name, min: 2, max: 80)
    |> validate_length(:bio, max: 600)
    |> validate_inclusion(:locale, ~w(en uk ru))
    |> validate_url(:tip_url)
  end

  def moderation_changeset(user, attrs) do
    user
    |> cast(attrs, [:moderation_status, :moderation_note])
    |> validate_required([:moderation_status])
    |> validate_length(:moderation_note, max: 1_000)
  end

  def role_changeset(user, attrs) do
    user
    |> cast(attrs, [:role])
    |> validate_required([:role])
  end

  defp validate_url(changeset, field) do
    validate_change(changeset, field, fn ^field, value ->
      case URI.parse(value) do
        %URI{scheme: scheme, host: host} when scheme in ["https", "http"] and is_binary(host) ->
          []

        _ ->
          [{field, "must be a full http(s) URL"}]
      end
    end)
  end

  defp validate_email(changeset, opts) do
    changeset =
      changeset
      |> validate_required([:email])
      |> validate_format(:email, ~r/^[^@,;\s]+@[^@,;\s]+$/,
        message: "must have the @ sign and no spaces"
      )
      |> validate_length(:email, max: 160)

    if Keyword.get(opts, :validate_unique, true) do
      changeset
      |> unsafe_validate_unique(:email, WhoNeedHelp.Repo)
      |> unique_constraint(:email)
      |> validate_email_changed()
    else
      changeset
    end
  end

  defp validate_email_changed(changeset) do
    if get_field(changeset, :email) && get_change(changeset, :email) == nil do
      add_error(changeset, :email, "did not change")
    else
      changeset
    end
  end

  @doc """
  A user changeset for changing the password.

  It is important to validate the length of the password, as long passwords may
  be very expensive to hash for certain algorithms.

  ## Options

    * `:hash_password` - Hashes the password so it can be stored securely
      in the database and ensures the password field is cleared to prevent
      leaks in the logs. If password hashing is not needed and clearing the
      password field is not desired (like when using this changeset for
      validations on a LiveView form), this option can be set to `false`.
      Defaults to `true`.
  """
  def password_changeset(user, attrs, opts \\ []) do
    user
    |> cast(attrs, [:password])
    |> validate_confirmation(:password, message: "does not match password")
    |> validate_password(opts)
  end

  defp validate_password(changeset, opts) do
    changeset
    |> validate_required([:password])
    |> validate_length(:password, min: 12, max: 72)
    # Examples of additional password validation:
    # |> validate_format(:password, ~r/[a-z]/, message: "at least one lower case character")
    # |> validate_format(:password, ~r/[A-Z]/, message: "at least one upper case character")
    # |> validate_format(:password, ~r/[!?@#$%^&*_0-9]/, message: "at least one digit or punctuation character")
    |> maybe_hash_password(opts)
  end

  defp maybe_hash_password(changeset, opts) do
    hash_password? = Keyword.get(opts, :hash_password, true)
    password = get_change(changeset, :password)

    if hash_password? && password && changeset.valid? do
      changeset
      # If using Bcrypt, then further validate it is at most 72 bytes long
      |> validate_length(:password, max: 72, count: :bytes)
      # Hashing could be done with `Ecto.Changeset.prepare_changes/2`, but that
      # would keep the database transaction open longer and hurt performance.
      |> put_change(:hashed_password, Bcrypt.hash_pwd_salt(password))
      |> delete_change(:password)
    else
      changeset
    end
  end

  @doc """
  Confirms the account by setting `confirmed_at`.
  """
  def confirm_changeset(user) do
    now = DateTime.utc_now(:second)
    change(user, confirmed_at: now)
  end

  @doc """
  Verifies the password.

  If there is no user or the user doesn't have a password, we call
  `Bcrypt.no_user_verify/0` to avoid timing attacks.
  """
  def valid_password?(%WhoNeedHelp.Accounts.User{hashed_password: hashed_password}, password)
      when is_binary(hashed_password) and byte_size(password) > 0 do
    Bcrypt.verify_pass(password, hashed_password)
  end

  def valid_password?(_, _) do
    Bcrypt.no_user_verify()
    false
  end
end